block ZPtrListItem {
  pointer Data;
  
  pointer Next;
}

class ZPtrList {
  pointer First;
  pointer Last;
  
  
  procedure Deinit() {
    uses esi edi;    
    esi = this.First as ZPtrListItem;
  
    while (esi <> nil) {
      edi = esi.Next;
      GlobalFree(esi);
      esi = edi;      
    }
    this.First = nil;
    this.Last = nil;
  }
  
  function AddPointer(pointer inPtr) {
    uses ecx;
    
    eax = GlobalAlloc(GPTR, sizeof ZPtrListItem);
    eax as ZPtrListItem;
    eax.Data = inPtr;
    if (this.First == nil) {
      this.First = eax;
      this.Last = eax;
    } else {  
      ecx = this.Last as ZPtrListItem;
      ecx.Next = eax;
      this.Last = eax;
    }
  }
  
  function GetDataByIndex(int32 index) {
    if (this.First == nil) {
      return 0;
    }
    
    uses ecx edx;
    
    ecx = xor;
    eax = index;
    edx = this.First as ZPtrListItem;    
    while (eax != ecx) {
      if ([edx+4] == nil) {
        return 0;
      }
      edx = edx.Next;
      ecx++;
    }
    eax = edx.Data;
  }
  
  procedure DeleteIndex(int32 index) {
    uses ecx edx;
    ecx = xor;
    eax = index;
    eax--;
    edx = this.First as ZPtrListItem;    
    while (eax != ecx) {      
      edx = edx.Next;
      ecx++;
    }
    ecx = edx.Next as ZPtrListItem;
    eax = ecx.Next;
    edx.Next = eax;
    GlobalFree(ecx);
  }
}

ZPtrList myIntList;
myIntList = new ZPtrList;
edi = myIntList as ZPtrList;


for (ecx = 1 to 1000) {
  edi.AddPointer(ecx);
}

edi.DeleteIndex(996);

for (ecx = 0 to 998) {
  eax = edi.GetDataByIndex(ecx);
  printd(eax);
}

edi.Deinit();

delete myIntList;