//
// Copyright (c) OverHertz Ltd.
// Permission is granted to modify and use this code with your projects.
// Compile Compatibility. Ziron 1.1.28.1+
//

program WIN32CUI 'DC-Bot';

#include 'ch.zir';
#include 'wsock32.zir';
#include 'dclib/dcutils.zir';

//consts (settings)
const BOTNAME = 'ZIRON';
const DC_TAG = '<ApexDC++ V:1.5.1,M:A,H:0/1/7,S:1>';
const HUBIP = '127.0.0.1';
const HUBPORT = 411;


////////////////////////////////////////////////////////

//useful macros
inline function strCompare(s1, s2) {
  strCmp($s1, $s2);
  $return eax;
}

//globals
WSADATA wsa_Data;
WSOCKET sock;
SOCKADDR_IN sin;

char buf1[2048], buf2[1024];


//code
sin.sin_addr = inet_addr(HUBIP);
sin.sin_family = AF_INET;
sin.sin_port = htons(HUBPORT);

WSAStartup(WSOCKVER2_2, @wsa_Data);
sock = socket(AF_INET, SOCK_STREAM, 0);

connect(sock, @sin, sizeof SOCKADDR_IN);

repeat {
  buf1 = 0;
  
  eax = 2048;
  edi = @buf1;
  
  @fill:
  
  //begin receiving
  eax = recv(sock, edi, eax, 0);
  if (eax == -1) {
    print('Connection closed\r\n');
    break;
  } elseif (eax == 0) {
    print('Connection closed\r\n');
    break;
  }
  char[edi+eax] = 0;
  edi = @buf1;
  
  eax = strLen(@buf1);
  
  dl = [edi+eax-1];
  if (dl <> "|") {
    edi += eax;  

    edx = 2048;
    edx -= eax;
    eax = edx;
    
    goto @fill;
  }  
  
  if (char*[edi] == "$Loc" and word[edi+4] == "k ") {
    edi += 6;
  
    eax = strOffset(edi, '|');
    [eax] = 0;
  
    eax = DC_LockToKey(@buf1, @buf2);
    push eax
    send(sock, '$Supports UserCommand UserIP2 TTHSearch ZPipe0 GetZBlock |', sizeof '$Supports UserCommand UserIP2 TTHSearch ZPipe0 GetZBlock |', 0);  
    pop eax
    send(sock, @buf2, eax, 0);
    send(sock, '$ValidateNick '+BOTNAME+'|', sizeof '$ValidateNick '+BOTNAME+'|', 0);
  } elseif (char*[edi] == "$Sup" and char*[edi+4] == "port" and word[edi+8] == "s ") {
    send(sock, '$Version 1,0091|$GetNickList|$MyINFO $ALL '+BOTNAME+' '+DC_TAG+'$ $100?$$0$|', sizeof '$Version 1,0091|$GetNickList|$MyINFO $ALL '+BOTNAME+' '+DC_TAG+'$ $100?$$0$|', 0);
  } elseif (char[edi] == "<") {
    print(edi:string, '\r\n');
    
    //chat message
    edi = strOffset(@buf1, '>');
    edi += 2;
    
    if (char*[edi] == "zir ") {
      if (char*[edi+4] == "say ") {
        eax = strSub(@buf2, edi, 8, 1024);
        push eax
        send(sock, '<'+BOTNAME+'> ', sizeof '<'+BOTNAME+'> ', 0);
        pop eax
        send(sock, @buf2, eax, 0);
      } elseif (char*[edi+4] == "quit") {
        send(sock, '<'+BOTNAME+'> Goodbyte!|', sizeof '<'+BOTNAME+'> Goodbyte!|', 0);
        break;
      }
    }
  }
};

closesocket(sock);
WSACleanup();

wait_key(nil);
ExitProcess(0);

 eax = recv(sock, edi, eax, 0);
  if (eax == -1) {
    print('Connection closed\r\n');
    break;
  } elseif (eax == 0) {
    print('Connection closed\r\n');
    break;
  }

 eax = recv(sock, edi, eax, 0);
  if (eax < 1) {
    print('Connection closed\r\n');
    break;
  }

 if (eax < 1) 

if ((int32)eax < 1) {

//
// Copyright (c) OverHertz Ltd.
// Permission is granted to modify and use this code with your projects.
// Compile Compatibility. Ziron 1.1.28.1+
//

program WIN32CUI 'DC-Bot';

#include 'ch.zir';
#include 'wsock32.zir';
#include 'dclib/dcutils.zir';
#include 'colors.zir';

//consts (settings)
const BOTNAME = 'ZIRON';
const DC_TAG = '<ApexDC++ V:1.5.1,M:A,H:0/1/7,S:1>';
const HUBIP = '127.0.0.1';
const HUBPORT = 411;
const BUFFERSIZE = 2048;

////////////////////////////////////////////////////////


//useful macros
inline function strCompare(s1, s2) {
  strCmp($s1, $s2);
  $return eax;
}

//globals
WSADATA wsa_Data;
SOCKADDR_IN sin;
WSOCKET sock;

char buf1[BUFFERSIZE], buf2[1024];

function InitClient() {
  eax = WSAStartup(WSOCKVER2_2, @wsa_Data);
  if (eax != 0) {
    print('wsastartup failed\r\n');
    return false;
  }

  //code
  sin.sin_addr = inet_addr(HUBIP);
  sin.sin_family = AF_INET;
  sin.sin_port = htons(HUBPORT);

  sock = socket(AF_INET, SOCK_STREAM, IPPROTO_TCP);
  if (sock == INVALID_SOCKET) {
    print('invalid socket\r\n');
    return false;
  }

  eax = connect(sock, @sin, sizeof SOCKADDR_IN);
  if (eax == SOCKET_ERROR) {
    eax = WSAGetLastError();
  
    print('socket connect error (',eax:int,')\r\n');
    return false;
  }
  
  eax = true;
}

function ReceiveDCData(DWord ofs) {
  uses esi edi;
  esi = @buf1;
  add esi, ofs
  
  edi = BUFFERSIZE;
  repeat {
    if (edi < 1) {
      //data is too long we will scrap the current buffer and try begin receiving again.
      esi = @buf1;
      edi = BUFFERSIZE;
    }
    eax = recv(sock, esi, edi, 0);
  
    if (eax == -1) {
      print('socket error\r\n');
      return false;
    } elseif (eax == 0) {
      print('socket gracefully closed\r\n');
      return false;
    }
    char[esi+eax] = 0;
    esi += eax;
    edi -= eax;
    
    eax = strIndexOf(@buf1, '|');
  } until (eax != -1);
  
  esi = @buf1;
  //seal the buffer and return the offset
  char[esi+eax] = 0;
  
  eax++;
}

procedure EchoMessage(char* msg; DWord col) {
  SetConsoleTextAttribute(hStdOut, col);
  print(msg, '\r\n');
}

function ProcessBuffer(DWord len) {
  uses esi;  
  esi = @buf1;
  
  repeat {
  
    //process the line....  
    if (char*[esi] == "$Loc" and word[esi+4] == "k ") {    
      send(sock, '$Supports UserCommand UserIP2 TTHSearch ZPipe0 GetZBlock |', sizeof '$Supports UserCommand UserIP2 TTHSearch ZPipe0 GetZBlock |', 0);      
      eax = DC_LockToKey(esi, @buf2);
      send(sock, @buf2, eax, 0);
      send(sock, '$ValidateNick '+BOTNAME+'|', sizeof '$ValidateNick '+BOTNAME+'|', 0);
      
    } elseif (char*[esi] == "$Sup" and char*[esi+4] == "port" and word[esi+8] == "s ") {
      eax = send(sock, '$Version 1,0091|$GetNickList|$MyINFO $ALL '+BOTNAME+' '+DC_TAG+'$ $100?$$0$|', sizeof '$Version 1,0091|$GetNickList|$MyINFO $ALL '+BOTNAME+' '+DC_TAG+'$ $100?$$0$|', 0);      
      
    } elseif (char*[esi] == "$Hub" and char*[esi+4] == "Name" and char[esi+8] == " ") {
      lea eax, [esi+9];      
      SetConsoleTitle(eax);
      
    } elseif (char[esi] == "$") {
      EchoMessage(esi:string, FOREGROUND_RED);
      
    } else {
      //text message
      EchoMessage(esi:string, CONSOLE_DEFAULT);
    }
            
    //
    
    //fold the string
    eax = strFold(esi, len);
    eax = strIndexOf(esi, '|');
    
    if (eax == -1) {
      break;
    }
    
    //seal the |
    char[esi+eax] = 0;
    eax++;
    
    //update length
    len = eax;
  };
  
  //return what is left of the buffer.
  eax = strLen(@buf1);
}


eax = InitClient();

if (eax == true) {
  eax = xor;
  repeat {
    eax = ReceiveDCData(eax);
    if (eax == false) {
      break;
    }
  
    eax = ProcessBuffer(eax);
  };
  
  shutdown(sock, SD_BOTH);  
}
closesocket(sock);
WSACleanup();

wait_key(nil);
ExitProcess(0);